您现在的位置:首页 >> 老y讨论区 >> 程序讨论 >> 添加 找回密码 功能,重置密码发送到邮箱,不知道能不能发表?
程序讨论版须知:

在使用老y文章管理系统中的一些问题!对非本程序方面的问题恕不解答!对Html,css等基础问题恕不解答!如果没有HTML基础请先自学HTML!

需要打开你网站才能看出问题的请留下网址,并请保留本站版权及友情链接,否则不予回复。

 程序讨论  站长交流  链接交换  商业用户区
 
楼主Time:2016/5/25 0:36:21
江西蓝佰实业有限公司
  • 等级:注册会员
  • 注册:2016-05-25
  • Y币:15 元
添加 找回密码 功能,重置密码发送到邮箱,不知道能不能发表?
关键字:密码 邮箱
<!--#include file="../Inc/conn.asp"-->
<!--#include file="../Inc/md5.asp"-->
<%
If useroff=0 then Call Alert("网站目前已经关闭会员功能","../")
if request("action") = "zhaohui" then 
call zhaohui()
else
call list()
end if

Sub zhaohui

UserName = CheckStr(trim(request.form("UserName")))
email = CheckStr(trim(request.form("email")))

if UserName="" then
Call Alert ("请输入用户名","-1")
end if
if email="" then
Call Alert ("请输入电子邮箱","-1")
End if

Set rst = Server.CreateObject("ADODB.Recordset")
rst.Open "Select [username],[email] From ["&tbname&"_User] where Email='" &email&"' and username='" &UserName&"'" , conn, 1,3
if rst.bof then
Call Alert ("用户名或邮箱错误!","-1")
End if
rst.close
set rst=nothing




'------------生成随机密码-------------

Randomize 
Do While Len(pass)<8 '随机密码位数 
num1=CStr(Chr((57-48)*rnd+48)) '0~9 
num2=CStr(Chr((90-65)*rnd+65)) 'A~Z 
num3=CStr(Chr((122-97)*rnd+97)) 'a~z 
pass=pass&num3&num1&num2 
loop 

'------------生成随机密码-------------

Set rs = Server.CreateObject("ADODB.Recordset")
rs.Open "Select [password] From ["&tbname&"_User] where username='" &UserName&"'", conn, 3,3
if not rs.bof then
rs("PassWord")=md5(pass,16)
rs.update
end if
rs.close
set rs=nothing

'-------------发送电子邮件-----------------

zw="您好!<br>尊敬的用户 :"&UserName&" <br>您的临时新密码为<font color='red'>"&pass&"</font>,请尽快登录本站修改密码。<br><br>"&sitetitle&"<br>网站:"&siteurl
SendEmail email,sitetitle&"-找回密码",zw,2

'--------------发送电子邮件----------------

Call Alert ("操作成功,新密码已经发送到您的邮箱!",Request.ServerVariables("HTTP_REFERER"))
End Sub

Sub list
If LaoYID>0 then
Response.Redirect SitePath
End if
%>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
<meta name="keywords" content="<%=Sitekeywords%>" />
<link href="<%=SitePath%>images/css<%=Css%>.css" type=text/css rel=stylesheet>
<script type="text/javascript" src="<%=SitePath%>js/main.asp"></script>
<title>找回密码</title>
</head>
<body>
<div class="mwall">
<%=Head%>
<%=Menu%><div class="mw">
<div style='margin:100px auto;'>
  <form action="<%=SitePath%>User/Getpass.asp?action=zhaohui" method="post" name=loginForm>
<table width="390" border="0" align="center" cellpadding="0" cellspacing="0">
  <tr>
    <td height="30" colspan="2" align="center">请填写你的用户名和注册时填写的邮箱,系统将把新密码发送到您的邮箱!</td>
    </tr>
  <tr>
    <td width="150" height="30" align="right">用户名:</td>
    <td align="left"><input name="Username" class="borderall" type="text" size="15" style="width:100px;height:15px;"></td>
  </tr>
  <tr>
    <td width="150" height="30" align="right">邮 箱:</td>
    <td align="left"><input name="email" class="borderall" type="text" size="15" style="width:100px;height:15px;"></td>
  </tr>
  <tr>
    <td height="30" colspan="2"><input type="submit" name="Submit" value="找回登录密码" class="borderall" style="height:19px;"/></td>
  </tr>
</table>
</form>
</div>
</div>
<%=Copy%>
</div>
</body>
</html>
<%
End Sub



'-----------------------------------------------------------发送电子邮件

Sub SendEmail(Email,mailtitle,Mailbody,zj) 
On Error Resume Next


E_Server = "smtp.qq.com 这里写发件服务器" ''发件服务器 
E_ServerUser = "发件人邮箱登录名" ''登录用户名 
E_ServerPass = "发件人邮箱登录密码" ''登录密码 
E_SendManMail = "这里写发件人的邮箱地址" ''发件人邮件地址 
E_SendManName = "这里写发件人的姓名" ''发件人姓名



If zj="" or zj=1 Then

'JMail方法

Set JMail = Server.CreateObject("JMail.Message") 
JMail.silent=true 
JMail.Logging = True 
JMail.Charset = "gb2312" 
JMail.MailServerUserName = E_ServerUser
JMail.MailServerPassword = E_ServerPass
JMail.ContentType = "text/html" 
JMail.Priority = 1 
JMail.From = E_SendManMail 
JMail.FromName = E_SendManName 
JMail.AddRecipient Email
JMail.Subject = mailtitle
JMail.Body = Mailbody
JMail.Send (E_Server)
JMail.Close() 
Set JMail = Nothing 


Else

'IIS自带方法

Set objMail = Server.CreateObject("CDO.Message") 
Set objConfig = Server.CreateObject ("CDO.Configuration") 
objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465
objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = E_Server 
objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendusername") = E_ServerUser
objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendpassword") = E_ServerPass
objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/languagecode") = "0x0804"
objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
objConfig.Fields.Update() 
Set objMail.Configuration = objConfig
objMail.Subject = mailtitle
objMail.From = chr(34) & E_SendManName & chr(34) & E_SendManMail 
objMail.To = Email
objMail.HTMLBody = Mailbody
objMail.Send

objConfig.Close() 
Set objConfig = Nothing
objMail.Close() 
Set objMail = Nothing


End If


End Sub 

'-----------------------------------------------------------发送电子邮件结束
%>

[Top]
2 楼Time:2016/5/25 0:44:41
江西蓝佰实业有限公司
  • 等级:注册会员
  • 注册:2016-05-25
  • Y币:15 元
RE:添加 找回密码 功能,重置密码发送到邮箱,不知道能不能发表?
复制代码保存成 Getpass.asp
放到网站的user文件夹下。
然后自己到要用的地方加个超连接就可以了

[Top]
3 楼Time:2016/6/25 21:54:57
WuyuE
  • 等级:注册会员
  • 注册:2016-02-26
  • Y币:2 元
RE:添加 找回密码 功能,重置密码发送到邮箱,不知道能不能发表?
根本不行啊

[Top]
4 楼Time:2016/6/27 21:29:44
江西蓝佰实业有限公司
  • 等级:注册会员
  • 注册:2016-05-25
  • Y币:15 元
RE:添加 找回密码 功能,重置密码发送到邮箱,不知道能不能发表?
注意自己的网站空间是不是支持  JMail方法
支持的话,就把代码
SendEmail email,sitetitle&"-找回密码",zw,2
改成
SendEmail email,sitetitle&"-找回密码",zw,1

这个方面不要用QQ邮箱,可以用163之类的,同时你自己要去邮箱中开通 smtp 功能。

[Top]
5 楼Time:2016/6/27 21:42:48
江西蓝佰实业有限公司
  • 等级:注册会员
  • 注册:2016-05-25
  • Y币:15 元
RE:添加 找回密码 功能,重置密码发送到邮箱,不知道能不能发表?
163邮箱 开通SMTP
登录你的163邮箱之后,点设置 - POP3/SMTP/IMAP  勾选 POP3/SMTP服务 保存即可。



注意:E_ServerPass = "发件人邮箱登录密码" ''登录密码
这个地方的一般开通了邮箱的 POP3/SMTP服务 后,邮箱要求你设置或是直接给了你一个授权码或者发信密码之类的,   这里的 发件人邮箱登录密码 就必需写给的这个密码。

邮箱公司这么设计就是怕你的网站源代码泄露,那别人就可以登录你的邮箱了,有了授权码就不会泄露登录密码,邮箱就保住了。

-------------------------------
IIS自带CDO.Message组件能用的话是可以用QQ邮箱的。
我的就是用这种方法。

[Top]
6 楼Time:2016/7/5 22:02:22
晨夕
  • 等级:注册会员
  • 注册:2016-07-05
  • Y币:2 元
RE:添加 找回密码 功能,重置密码发送到邮箱,不知道能不能发表?
Microsoft VBScript 编译器错误 错误 '800a0409'

未结束的字符串常量

/user/getpass.asp,行 20

Call Alert ("璇疯緭鍏ョ數瀛愰偖绠?,"-1")
--------------------^

[Top]
7 楼Time:2016/7/5 22:03:26
晨夕
  • 等级:注册会员
  • 注册:2016-07-05
  • Y币:2 元
RE:添加 找回密码 功能,重置密码发送到邮箱,不知道能不能发表?

UserName = CheckStr(trim(request.form("UserName")))
email = CheckStr(trim(request.form("email")))

if UserName="" then
Call Alert ("请输入用户名","-1")
end if
if email="" then
Call Alert ("请输入电子邮箱","-1")   行 20
End if

Set rst = Server.CreateObject("ADODB.Recordset")
rst.Open "Select [username],[email] From ["&tbname&"_User] where Email='" &email&"' and username='" &UserName&"'" , conn, 1,3
if rst.bof then
Call Alert ("用户名或邮箱错误!","-1")
End if
rst.close
set rst=nothing

[Top]
8 楼Time:2016/7/6 23:53:42
江西蓝佰实业有限公司
  • 等级:注册会员
  • 注册:2016-05-25
  • Y币:15 元
RE:添加 找回密码 功能,重置密码发送到邮箱,不知道能不能发表?
你这是网页文件代码格式错误。
老Y是 gb2312 格式的。
你在保存的ASP文件的时候,不能保存 成 UTF-8格式的文件。

[Top]
9 楼Time:2016/7/6 23:56:51
江西蓝佰实业有限公司
  • 等级:注册会员
  • 注册:2016-05-25
  • Y币:15 元
RE:添加 找回密码 功能,重置密码发送到邮箱,不知道能不能发表?
用记事本保存文件,一般是选择 ANSI编码 保存

[Top]
10 楼Time:2016/9/14 17:47:28
小小乾坤路
  • 等级:注册会员
  • 注册:2016-08-28
  • Y币:40 元
RE:添加 找回密码 功能,重置密码发送到邮箱,不知道能不能发表?
并没什么用吧,收不到找回邮件

51电视刷机网www.51tvrom.com提供全面的智能电视ROM固件下载、机顶盒固件下载、第三方固件下载、官方刷机升级救砖固件下载,覆盖主流的海信电视件,TCL电视固件,康佳电视固件,长虹电视固件,乐视电视固件,暴风TV固件等等品牌固件,体验一站式刷机升级救砖服务,体验到刷机带来的乐趣。
[Top]

 
  标题:  
内容:
  44.221.43.88

购买咨询

QQ:97065691
商业技术支持

QQ:22862559

QQ:3978698